ETIQUETAS EM WORD

Public Sub etiquetas()

    Dim oApp As Word.Application
    Dim oDoc As Word.Document
    
    'Inicia um novo documento Word
    Set oApp = CreateObject("Word.Application")
    Set oDoc = oApp.Documents.Add
    
    With oDoc.MailMerge
    
    'Inclui os campos de mesclagens temporarios
    'Usamos os campos da tabela socios do banco de dados bd.mdb
     With .Fields
      .Add oApp.Selection.Range, "nome"
      oApp.Selection.TypeParagraph
      .Add oApp.Selection.Range, "morada"
      oApp.Selection.TypeParagraph
      .Add oApp.Selection.Range, "codpostal"
      
     End With
     Dim oAutoText As Word.AutoTextEntry
     Set oAutoText = oApp.NormalTemplate.AutoTextEntries.Add("MinhasEtiquetas", oDoc.Content)
    
     'os campos de mesclagens serão excluidos pois a entrada - AutoText foi gerada
     oDoc.Content.Delete
     
     'Define a mesclagens para etiquetas e usa um banco de dados
     'como fonte de dados , voce pode usar um arquivo texto|
     .MainDocumentType = wdMailingLabels
     'Informe aqui o caminho da fonte de dados
     '.OpenDataSource Name:="C:    este\etiqueta.txt" --> Voce pode usar um arquivo texto

     sDBPath = App.Path & "\base de dados\bd.mdb"
     .OpenDataSource Name:=sDBPath, SQLStatement:="SELECT * FROM tbl_socios"
    
     'Cria um novo documento para as etiquetas usando a entrada AutoText
     '5160 é o numero da etiqueta a usada
     oApp.MailingLabel.CreateNewDocument Name:="5160", Address:="", _
     AutoText:="MinhasEtiquetas", LaserTray:=wdPrinterManualFeed
     
     'Executa a mesclagem para gerar as etiquetas
     .Destination = wdSendToNewDocument
     .Execute
     
     'Excluir a entrada AutoText inserida
     oAutoText.Delete
    
    End With
    
    
    'fecha o documento original e torna o word visivel e exibe as etiquetas
    oDoc.Close False
    oApp.Visible = True
    ' Salva o modelo quando o usuario sair do word
    oApp.NormalTemplate.Saved = True

End Sub